; values in CAPS, self defined pointers and labels not,
; optimize for size rather than speed

	radix dec
;	processor pic16f627
	processor pic16f628a
	list n=0,st=off,mm=on

;#include "p16f627.inc" 
#include "p16f628a.inc" 

; initialize some preprocessor symbols
CONFIG_WORD = 0x3fff
OPTION_REG_CONFIG = 0

; set config word
CONFIG_WORD &= _CP_OFF & _DATA_CP_OFF	; turn all code protection off
CONFIG_WORD &= _LVP_OFF 		; disable Low Voltage Programming
CONFIG_WORD &= _BODEN_ON		; enable Brown-out Detect Reset
CONFIG_WORD &= _MCLRE_ON		; enable reset pin
CONFIG_WORD &= _PWRTE_ON		; enable power on timer
CONFIG_WORD &= _WDT_OFF			; disable Watchdog Timer
CONFIG_WORD &= _INTRC_OSC_NOCLKOUT	; enable internal oscillator

	__config CONFIG_WORD

; some useful definitions
RA0		equ	0		; RA0 is bit zero in PORTA

; file registers in bank 0,1,2,3
columns		equ	0x70		; amount of columns in eeprom
buffer_hi	equ	0x71		; the actual buffer (high bits)
buffer_lo	equ	0x72		; the actual buffer (low bits)
count0		equ	0x73		; useful counter for bit unpacking loop
outer_delay	equ     0x7e 		; delay routine
inner_delay	equ     0x7f		; counters for primitive

; font bitmaps in EEPROM, variable width 

	org 0x2100

start_text
#include "bla.inc"
end_text	

	org 0x0000

reset_vector ; the chip starts executing our code here

	movlw 1<<CM2|1<<CM1|1<<CM0	; disable Comparators
	movwf CMCON

	clrf PORTB			; init PORTB while still in bank 0

interrupt_vector	; interrupt vector is here, interrupts are disabled and
			; we don't need them, so we ignore the interrupt vector

	; we aim to be in bank 1 most of the time, PORTA/B will be
	; addressed through FSR and INDF

	bsf STATUS, RP0		; switch to bank 1

	;bcf PCON, OSCF		; use 37kHz clock (for debugging)

	movlw b'00000000'	; RB7:RB0 are outputs
	movwf TRISB

	movlw 0xFF		; RA7:RA0 are inputs
	movwf TRISA

	movlw PORTB
	movwf FSR

main_loop
	decf FSR, f			; switch to PORTA
	
standby
	btfss INDF, RA0	; start if button is pressed, otherwise wait
	goto standby

	call proc_long_delay

	movlw end_text - start_text - 1	
	movwf EEADR

	incf FSR, f			; switch to PORTB ( = PORTA + 1)

output_loop

	bsf EECON1, RD			; issue read command to EEPROM
	movf EEDATA, w			; read actual data
	decf EEADR, f			; increment EEPROM address

	movwf INDF
	call proc_short_delay

	clrf INDF
	call proc_short_delay

	btfss EEADR, 7			; check bit 7 to see if we warped
	goto output_loop	

	goto main_loop

proc_long_delay
	movlw 0x50			; non-debug value is 0x50
	movwf outer_delay
	goto outer_delay_loop

proc_short_delay
	movlw 0x02
	movwf outer_delay

outer_delay_loop   
	movlw 0xFF
	movwf inner_delay

inner_delay_loop
	decfsz inner_delay, f
	goto inner_delay_loop
		
	decfsz outer_delay, f
	goto outer_delay_loop

	return

	end